WonderFlで複数のクラスを使いたい場合
Tags: ActionScript
WonderFlでコンパイルできるのは1ファイルのみ(importできるのは指定されているライブラリのみ)。別ファイル化されているクラスを使いたくても使えないので、1ファイルに無理矢理押し込めてやる必要がある。» Fork me!!
一般仕様
//main.as package { import flash.display.Sprite; import com.borealkiss.Model; public class main extends Sprite{ public function main(){ } } }
//Model.as package com.borealkiss{ public class Model{ public function Main(){ } } }
WonderFl仕様
//All in one file package { import flash.display.Sprite; public class main extends Sprite{ public function main(){ } } } //No access modifier!!(i.e., public) class Model{ public function Model(){ } }
追記 2008/12/22
Flexアプリケーションが動いてる！！
色確認用 | Wonderfl Build Flash Online
インターフェイスにクラスを継承させる
Tags: ActionScript
注意:IEventDispatcherなどすでにインターフェイスが用意されているものについてはもっとスマートな実装方法がある(最下部の追記参照)
***************
インターフェイスはクラスではないのでクラスは継承できない。インターフェイスに他クラスの機能を扱えるようにして、あたかもクラスを継承しているようにする方法。
イントロダクション
親をインターフェイスで定義しておいて、その子クラスを使う場合、プログラム上では直接子クラスへの参照を作るのではなく親インターフェイスへの参照で扱う方が「後々」都合がよい場合が多い。例えばIDoSomethingインターフェイスを継承したDoSomethingクラスを作る場合は以下のように記述してやる。
package { import flash.display.Sprite; //main public class main extends Sprite{ //Defined as Interface private var _doSomething:IDoSomething; public function main(){ //Creates a DoSomething class. _doSomething = new DoSomething(); _doSomething.do(); } } } package{ public interface IDoSomething{ function do():void; } } package{ public class DoSomething implements IDoSomething{ public function do():void{ //Something is done. } } }
さてDoSomethingクラスは”クラス”なので、その他のクラスを継承することができる。例としてEventDispatcherクラスを継承させる。
package{ import flash.events.EventDispatcher; public class DoSomething extends EventDispatcher implements IDoSomething{ public function do():void{ //Do something } } }
本題
これでDoSomethingクラスはイベントの送受信ができるようになった。ここでようやく本題(の問題)に突入。先ほどmainクラスではDoSomethingクラスを使う際、DoSomethingクラスそのものではなく親インターフェイス(IDoSomething)への参照を用いて使うことにしていた。IDoSomethingへの参照変数に参照されたDoSomethingクラスがイベントを送信したらどうなるか。IDoSomething.dispatchEvent()メソッドはインターフェイスには定義されていないのでコンパイルエラーになる。
package { import flash.display.Sprite; import flash.events.Event; //main public class main extends Sprite{ //Defined as Interface private var _doSomething:IDoSomething; public function main(){ _doSomething = new DoSomething(); //Compile error as no such method is defined in the Interface. _doSomething.dispatchEvent(new Event("doSomething")); } } } package{ public interface IDoSomething{ function do():void; } } package{ import flash.events.EventDispatcher; public class DoSomething extends EventDispatcher implements IDoSomething{ public function do():void{ //Do something } } }
解決策
DoSomethingクラスではたしかに実装されているメソッドなのに、IDoSomethingインターフェイスでは定義されていない。それにもかかわらずmainクラスではIDoSomethingインターフェイスとして扱いたい場合どうするか。「実装したいメソッドを扱えるクラスを戻り値とする」メソッドを新たにインターフェイスに定義してやればよい。上記のEventDispathcerクラスのメソッドを扱いたい場合は、インターフェイスを以下のように再定義してやる。
package{ import flash.events.EventDispatcher; public interface IDoSomething{ function do():void; //New!! function get eventDispatcher():EventDispatcher; } }
そして、実際のメソッド内容を子クラスに追加、戻り値を子クラス自身とする。子クラスはEventDispatherクラスを継承しているところがポイント。
package{ import flash.events.EventDispatcher; public class DoSomething extends EventDispatcher implements IDoSomething{ //New!! public function get eventDispatcher():EventDispatcher{ return this; } public function do():void{ //Do something } } }
mainクラスは以下の通り。IDoSomething.eventDispatcher()メソッド経由でEventDispathcer.dispatchEvent()メソッドにアクセス。無事コンパイルが通る。
package { import flash.display.Sprite; import flash.events.Event; //main public class main extends Sprite{ //Defined as Interface private var _doSomething:IDoSomething; public function main(){ _doSomething = new DoSomething(); //Event successfully dispatched!! _doSomething.eventDispacther.dispatchEvent(new Event("do")); } } }
応用
同じようにして、例えば子クラスにDisplayObjectContainerクラスを継承させて、DisplayObjectContainerクラスを戻り値とするメソッドを定義してやれば、インターフェイスからDisplayObjectContainer.addChild()などを使うことができる。
package { import flash.display.Sprite; //main public class main extends Sprite{ public function main(){ var example:IExample = new Example(); var testSprite:Sprite = new Sprite(); //The interface acts as Sprite!! example.displayObjectContainer.addChild(testSprite); } } } package{ import flash.display.DisplayObjectContainer; public interface IExample{ function doExample():void; function get displayObjectContainer():DisplayObjectContainer; } } package{ import flash.display.Sprite; import flash.display.DisplayObjectContainer; public class Example extends Sprite implements IExample{ public function doExample():void{ } public function get displayObjectContainer():DisplayObjectContainer{ return this; } } }
***********************
追記 2008/12/14
やべえ。インターフェイスにはIEventDispatcherインターフェイスを継承させて、子クラスにはEventDispatcherクラスを継承させるだけで無茶苦茶スマートな構造になった。mutaさん thanks!!
package { import flash.display.Sprite; import flash.events.Event; public class main extends Sprite{ public function main(){ var doSomething:IDoSomething = new DoSomething(); doSomething.addEventListener(Event.COMPLETE,trace); doSomething.dispatchEvent(new Event(Event.COMPLETE)); } } } package{ import flash.events.IEventDispatcher; public interface IDoSomething extends IEventDispatcher{ } } package{ import flash.events.EventDispatcher; public class DoSomething extends EventDispatcher implements IDoSomething{ } }
[ActionScript] 25-Line ActionScript Contest 投票開始
Tags: ActionScript, FLASH
ActionScript 25行以内で何ができるかに焦点を絞ったコンテストの最終選考が一般投票形式でスタート。優勝賞品がCS4一式というのが関係あるのかしらんけど作品がどれも熱い！
The 25-Line ActionScript Contest » November/December Finalists
自分は最終選考には残らんかった。というか最終選考に残ってるやつどれも25行以内のActionScriptで動いてるとは到底思えんので自分的には納得してる。パッと見た限りでは木がランダムに生えるやつがキレイでツボ。メタボールのやつがソースコードがスッカスカでびびる。アスキーアートのゲームもネタ的に面白い。いやーしかしこれは良い刺激になったなあ。次回も是非参加したい。
ちなみに僕が応募したやつは[Flash] Unknown Pleasures - boreal-kiss.comを改良したやつ。ファイナリストに日本人見かけなかったけど他に日本人で応募した人とかいたのかしら。なんとなくドイツ人が多かった感じがした。
SpotlightFilter.as
Tags: ActionScript, FlashPlayer10
» Demo (Spotlightのとこ。要Flash Player 10)
Spark project - /as3/Astro/SpotlightFilterに一式をアップしてあるのでご利用ください(MITライセンス)。spotlight.pbkファイル作成者のRyan Phelanに確認したところ、pbkファイルを改変する場合はその内容もアップデートに含めたいので是非教えてくれとのこと。SpotlightFilter.as作成で参考にしたのはSpark project - /as3/Astro/RadialBlur。mutaさんのソースは勉強になるのでちょくちょく参考にさせてもらっている。とりあえずSpark project参加当初の目標(コミットする)は達成できた。
[DesignPatterns] Stateパターンでif文をなくす
Tags: ActionScript, DesignPatterns
プログラミングテクニックのまとめ - プログラミング日記の「ifをポリモーフィズムによりなくせ」に相当するものをActionScriptで実践した。以下の例では分岐が高々2箇所なのでif文をなくす労力の方が無駄に思えるが、if文やswitch文の分岐箇所が増えるような場合ほど威力を発揮するはず(拡張が容易・メンテナンスが楽などの理由)。
a. if文が必要な場合
例えば線を描画したいとき、描画始点はGraphics.moveTo()、その他はGraphics.lineTo()を使う。そのため以下の例のようにforループでArrayデータの内容を読み込んで折れ線グラフを描画させるルーチン内ではif文を使う必要がある。
package { import flash.display.Sprite; import flash.display.Shape; public class Main extends Sprite{ private var _drawer:Shape; private var _data:Array = [0,10,0,10,0,10,0,10,0,10];//Test data public function Main(){ _drawer = new Shape(); addChild(_drawer); draw(); } private function draw():void{ _drawer.graphics.lineStyle(1,0x0); for (var i:int=0; i<_data.length; i++){ var x:Number = 20*i; var y:Number = 20*_data[i]; if (i==0){ _drawer.graphics.moveTo(x,y); } else { _drawer.graphics.lineTo(x,y); } } } } }
この分岐処理はGraphics.moveTo()とGraphics.lineTo()という全く別のメソッドを「直接」使うから生じている。つまり、これらメソッドをコントロールする管理クラスを新たに作って、管理クラス経由で「間接」的に扱えば(delegateする、と言う)回避することが可能になるわけだ。具体的にはforループ内ではその管理クラスの単一メソッドのみを呼び出すようにする。
b. if文が不要な場合
以下の例では管理クラスLineDrawer.asを導入して描画させている。線の始点であろうがなかろうが常にLineDrawer.draw()というメソッドを使うので結果if文がなくなっている。
package { import flash.display.Sprite; import com.borealkiss.controls.LineDrawer; public class Main extends Sprite{ private var _drawer:LineDrawer; private var _data:Array = [0,10,0,10,0,10,0,10,0,10];//Test data public function Main(){ _drawer = new LineDrawer(); addChild(_drawer); draw(); } private function draw():void{ _drawer.graphics.lineStyle(1,0x0); for (var i:int=0; i<_data.length; i++){ var x:Number = 20*i; var y:Number = 20*_data[i]; _drawer.draw(x,y); } } } }
以下if文がなくなったカラクリ部分について。
b-1. LineDrawer.as (管理クラス)
Main.asから呼ばれるのはLineDrawer.draw()メソッドのみ。ポイントはLineDrawer.draw()内で実際に働く中身の入れ替えを行っているところ。最初にLineDrawer.draw()が呼ばれたときに実際に働くのがプロパティ”_moveToState”にセットされたクラス(MoveToState.as)、それ以降はプロパティ”_lineToState”にセットされた「別」クラス(LineToState.as)で、それぞれdraw()というメソッドを持っているがメソッドの内容は全く別物になっている(b-3, b-4参照)。そしてこの二つのクラスの受け皿に担当するプロパティ”_currentState”はこの両クラスを参照できるようにそれぞれの同一継承元であるクラス型(IState.as)で定義されている。これがポリモーフィズム(クラス型の多様性)。イメージとしてはクラス型を日本人型に設定しておき、東京人型クラスも大阪人型クラスも参照できるような状態。
package com.borealkiss.controls{ import flash.display.Shape; public class LineDrawer extends Shape{ private var _moveToState:IState; private var _lineToState:IState; private var _currentState:IState; public function LineDrawer(){ _moveToState = new MoveToState(this); _lineToState = new LineToState(this); init(); } public function draw(x:Number,y:Number):void{ _currentState.draw(x,y); _currentState = _lineToState; } public function init():void{ _currentState = _moveToState; } } }
b-2. IState.as (インターフェイス)
LineDrawer.as(管理クラス)内で呼び出されて働かされるクラスMoveToState.asとLineToState.asが継承している親玉クラス。これがあるからポリモーフィズムが可能になる。重要なのはMoveToStateクラスとLineToStateクラスが共通して継承しているクラスが存在していることなので、インターフェイスを使わなくてもアブストラクト的なクラスを作成して代用してもよい(MoveToState extends XXX, LineToState extends XXX, のXXXに相当するクラス)。
package com.borealkiss.controls{ public interface IState{ function draw(x:Number,y:Number):void; } }
b-3. MoveToState.as
折れ線グラフの始点描画時点でのみ呼ばれるクラス。MoveToState.draw()はGraphics.moveTo()を実際に行う。
package com.borealkiss.controls{ public class MoveToState implements IState{ protected var _drawer:LineDrawer; public function MoveToState(drawer:LineDrawer){ _drawer = drawer; } public function draw(x:Number,y:Number):void{ _drawer.graphics.moveTo(x,y); } } }
b-4. LineToState.as
折れ線グラフの始点以降で呼ばれるクラス。LineToState.draw()はGraphics.lineTo()を実際に行う。MoveToStateクラスを継承しているので必然的にIStateインターフェースも継承している。
package com.borealkiss.controls{ public class LineToState extends MoveToState{ public function LineToState(drawer:LineDrawer){ super(drawer); } override public function draw(x:Number,y:Number):void{ _drawer.graphics.lineTo(x,y); } } }
追記 2008/12/17
以下の記事で引用いただいたのですが、プログラミングの思想という点で大変参考になります。extendsとかimplementsが好きな方にオススメ。